【原创】MT快捷组<->IE收藏夹 互转cmd脚本

[hitme]

中午星，快睡着了，注意备份

快捷组cgp->收藏夹url

conv_c_u.cmd
MT Groups目录下运行

@echo off
setlocal ENABLEDELAYEDEXPANSION

for %%a in (*.cgp) do (
		set pathu=ie_url\%%~na
		md !pathu!
		set /a n=0
		for /f "skip=1 tokens=1* delims==" %%i in (%%a) do (
				if "%%i"=="[Properties]" (set /a n=1) else (
									 	if !n!==0 (
									 		   echo [InternetShortcut]>>"!pathu!\%%i".url 
											   echo URL=%%j>>"!pathu!\%%i".url) 
									   )
		)
)
endlocal

=========================================================

收藏夹url->快捷组cgp

conv_u_c.cmd
IE_Favorites目录下运行

@echo off

echo [CaptorGroup]>>url.cgp
for /f %%i in ('dir /b/ad') do (
				echo [CaptorGroup]>>%%i.cgp
)

setlocal ENABLEDELAYEDEXPANSION
for /f "usebackq tokens=1,2* delims=\=" %%i in (`findstr /s /r "^URL=" *.url^|findstr "\\"`) do (
									set n=%%j
									echo !n:~0,-8!=%%k>>%%i.cgp 
)

for /f "usebackq tokens=1* delims=\=" %%i in (`findstr /s /r "^URL=" *.url^|findstr /v "\\"`) do (
									set n=%%i
									echo !n:~0,-8!=%%j>>url.cgp 
)

endlocal

[ultrac]

非常好用，谢谢！！！

[hitme]

作者: ultrac

非常好用，谢谢！！！

劳务费~~劳务费~~hoho
民工的钱是不能欠的
不给我就要跳
你试试看?
好嘛..
啵!